Rooba
/
ReC98
mirror of https://github.com/nmlgc/ReC98.git
1
1
Fork 0
Code Issues Packages Projects Releases Wiki Activity
ReC98/th04/hardware/snd_determine_modes.asm

92 lines
2.0 KiB
NASM
Raw Normal View History

[Reverse-engineering] Sound mode determination Note how it's only one *mode* in TH02/TH03, but two *modes* in TH04/TH05, since you can't select between FM and Beep sound effect modes in TH02/TH03 (or even disable sounds altogether). Might be a bit confusing, but it seemed appropriate enough to distinguish the two functions.
2014-11-28 23:56:26 +00:00
; Checks the requested BGM and SE modes against the available hardware and
; sets snd_se_mode and snd_bgm_mode accordingly.
; Returns snd_bgm_mode, but the game doesn't care.
Use TASM calling convention syntax for previously identified ZUN functions With TH03 changing the calling convention for most of the code from __cdecl to __pascal, I've been getting more and more confused about this myself. So, let's settle on the following consistent syntax for function calls: * C where the calling convention is actually __cdecl and where TASM's emitted __cdecl code matches the original binary * PASCAL where the calling convention is actually __pascal * STDCALL where the calling convention is actually __cdecl, but where the caller either defers stack cleanup (summing up the stack size of multiple functions, then cleaning it all in a single "add sp" instruction) or where the stack is cleared in a different way (e.g. "pop cx"). Unfortunately though, when using the ARG directive to automatically generate an appropriate RET instruction for the given calling convention, TASM always emits ENTER and LEAVE instructions even when no local variables are declared, which greatly limits the number of functions where we can use that syntax. -.-
2014-12-16 04:53:56 +00:00
; int __pascal snd_determine_modes(int req_bgm_mode, int req_se_mode)
[Reverse-engineering] Sound mode determination Note how it's only one *mode* in TH02/TH03, but two *modes* in TH04/TH05, since you can't select between FM and Beep sound effect modes in TH02/TH03 (or even disable sounds altogether). Might be a bit confusing, but it seemed appropriate enough to distinguish the two functions.
2014-11-28 23:56:26 +00:00
snd_determine_modes proc
@@req_se_mode = word ptr (cPtrSize + 2)
@@req_bgm_mode = word ptr (cPtrSize + 4)
push bp
mov bp, sp
push si
push di
mov si, [bp+@@req_bgm_mode]
mov di, [bp+@@req_se_mode]
nopcall snd_pmd_resident
cmp si, SND_BGM_MIDI
jne short @@check_PMD
nopcall snd_mmd_resident
@@check_PMD:
mov ah, PMD_GET_DRIVER_VERSION
int 60h
cmp al, -1
jne short @@got_PMD
mov snd_bgm_mode, SND_BGM_OFF
jmp short @@FM_SE_requested?
@@got_PMD:
or al, al ; 1 == running a 26 board, 2 == running a 86 board
jne short @@got_PMD86
mov snd_bgm_mode, SND_BGM_FM26
jmp short @@FM_SE_requested?
@@got_PMD86:
mov snd_bgm_mode, SND_BGM_FM86
@@FM_SE_requested?:
cmp di, SND_SE_FM
jne short @@Beep_SE_requested?
cmp snd_bgm_mode, SND_BGM_OFF
je short @@FM_SE_requested_but_got_no_board
mov ax, SND_SE_FM
jmp short @@decide_SE_if_FM_requested
@@FM_SE_requested_but_got_no_board:
xor ax, ax
@@decide_SE_if_FM_requested:
mov snd_se_mode, al
jmp short @@do_we_even_want_BGM?
@@Beep_SE_requested?:
cmp di, SND_SE_BEEP
jne short @@no_SE_requested
mov snd_se_mode, SND_SE_BEEP
jmp short @@do_we_even_want_BGM?
@@no_SE_requested:
mov snd_se_mode, SND_SE_OFF
; Since we tentatively set snd_bgm_mode when checking the driver above...
@@do_we_even_want_BGM?:
or si, si
jne short @@MIDI_requested?
mov snd_bgm_mode, SND_BGM_OFF
jmp short @@ret
@@MIDI_requested?:
cmp si, SND_BGM_MIDI
jnz short @@FM26_requested?
cmp snd_midi_possible, 0
jz short @@FM26_requested?
mov snd_bgm_mode, SND_BGM_MIDI
jmp short @@ret
@@FM26_requested?:
cmp si, SND_BGM_FM26
jnz short @@ret
cmp snd_bgm_mode, SND_BGM_OFF
jz short @@ret
mov snd_bgm_mode, SND_BGM_FM26
@@ret:
mov al, snd_bgm_mode
mov ah, 0
pop di
pop si
pop bp
ret 4
snd_determine_modes endp